类是什么?
类是 VB / VBA 中的一个模块,它是一个特殊的模块。类用于 Hold 住代码和数据,这些代码和数据用于描述某个对象,实现该对象的行为和属性。让类区别于 VB / VBA 中其他模块的是,类是完整加载于内存中的,而且可以加载不止一次。实际上,每实例化一个对象的时候,类就会被加载一次。
在设计类的时候,使用数据范式模型是很有用的。表是对象的模型,在设计表的时候,最好不要将 2 个及以上的对象建模到 1 张表里面。同样的道理,类也应该只对单一对象建模。我们应该避免让类 Hold 住或实现 2 个及以上的不同的对象。假设你有一个“银行”类,那么这个类应该使用诸如“账户”,“客户”,“支票”,“存款”等银行相关的类,这些类中,每一个都只需要存储它所建模的对象的数据,也只需要放置它所建模的对象行为的实现代码。如果一个类既描述银行,同时又描述账户,客户等,那注定乱成一团。
所以,如果一个类描述了一张支票,那么它肯定有支票号码属性,签发日期属性,金额属性,签名属性等。直到被加载到内存,这个类才可以描述任何能与它相匹配的支票。在这个类加载到内存,这些属性都赋值数据之前,它是不能描述任何东西的。这张支票号码是 1234,签发日期是 2000 年 1 月 1 日,金额 $123.45,是由史密斯先生签发。这个类的实例才描述了一张特定的支票。如果有一堆支票,你需要用类来管理它们,那么你需要为每一张支票都加载一个类的实例。
类通常都会在内存中加载多次,用来描述某个对象的多个实例。然而这并不是必须。我们也可以设计只加载一次的类,在这种情况下,开发者主要看中了类的封装特性。将所有的代码和变量都集中放在一个地方,类被实例化成对象后,这个对象知道如何来做一些事情。举例来说,我的框架有一个框架类。这个类只加载一次。这个类知道如何从表中读取加载参数,配置自己的属性,它也知道如何加载其他的服务类,例如 MD5 加密类,它也知道如何计算应用程序加载的对象的个数。这样,在标准模块中定义一个变量,运行一个函数,这个函数将我的框架类的实例赋给这个变量,然后初始化这个类的实例,一环套一环的事件发生,让其他的类也加载到内存,我的应用程序被设置好,准备开始工作了。当这些做完后,我可以调用我的框架类的方法,为我提供服务:压缩 / 解压缩文件,加密 / 解密文件,以及更一般的充当框架管理的角色。
总的来说,类是一种特殊的模块,这个模块中存储的是代码和数据,这些代码和数据是用来描述某个对象的行为和属性,每个加载到内存中的实例都对应着一个对象,这些对象可以用来帮我们做一些事情。
为何要使用类?
我已经简单的描述了类,现在,让我们来使用它。首先,每一个窗体都有(或都可以有)一个内建类(Built in class),当加载这个窗体时,这个内建类的一个实例就被加载到内存。这个内建类中有一些事件,例如打开事件(Open),关闭事件(Close)和更新后事件(AfterUpdate)。它也能被用来为窗体本身设置属性。对任何类来讲,ME 这个关键字是用来指代这个类的当前实例。换句话讲,如果你想在代码中设置窗体的标题属性,可以使用代码 Me.Caption=”Some text” 。因为“窗体后面的代码” 是驻留在窗体的类中,任何在窗体中写过代码的 Access 开发者就已经使用过类了。
类是窗体的一部分,这个事实非常美好的一点在于,你可以导出这个窗体到另一个数据库,窗体模块(类)中的代码也被跟着一起导出了。不幸的是,这也导致了一些维护上的困难,如果你在窗体模块(类)中写了非常复杂的代码,在另一个窗体中也需要相同的代码的话。很多开发者只是简单的复制和粘贴这些代码到另一个窗体中就完事了。如果代码有 Bug 怎么办?你需要打开 2 个窗体,清除这个 Bug。如果你将这个窗体导出到了另外一个项目中怎么办?你需要打开 2 个项目,修改代码清除 Bug。
认识到这是一个问题后,一些开发者开发了库(Libraries),将这些代码保存到他们自己的库中。这种方式运行得非常好(这也是我的做法)。现在,如果一个文本框的 OnEnter 事件需要调用一个函数,这个函数在库中,两个窗体都调用这个相同的函数。如果这个函数有 Bug,在库中修复这个 Bug,任何使用这个函数的地方就都没问题了。这种方法比之前好多了。
然而我们仍然有事件本身的问题。为了让复选框的 OnEnter 事件调用一个方法,这个事件会执行一段代码。对 99% 的 Access 程序员来讲,这段代码都会放在复选框所在窗体的窗体模块(类)中。我并不是说这种方式有什么不对,但是当一个大的窗体上有 10 个 标签页,80 个控件在其上时,每个控件触发 3 或 4 个不同的事件,再加上半打窗体本身的事件,再加上 30 个一般的执行调用函数,再加上……你懂了吧?现在这个窗体就像噩梦一样,非常难以维护。在海量的事件代码中,翻上翻下的来查找修改一点东西。
事实上,其他 Office 程序 (Word,Excel,Access,Powerpoint)的主要问题之一就是控件没有自己的类,与窗体不一样。因此,窗体类被当做了控件类。还记得之前说过的吗?类应该只为一个对象建模。我们现在已经遇到了一个类既为窗体建模,又为各种不同的控件建模。嗯……
下述示例演示了,当用户在控件中移动时,如何改变活动文本框的背景颜色。打开 frmPeople1 窗体,按 Tab 键观察一下活动光标。(点击该连接:Access框架研究系列之4 控件类示例下载本章所有示例代码文件)
Option Compare Database Option Explicit Private Const mclngBackColor As Long = 16777088 '颜色代码,用来设置文本框背景色 Private mlngBackColorOrigFName As Long Private mlngBackColorOrigLName As Long Private Sub txtFName_Enter() mlngBackColorOrigFName = txtFName.BackColor '当进入文本框,保存原始的背景色 txtFName.BackColor = mclngBackColor '将背景色设置成我们喜欢的颜色 End Sub Private Sub txtFName_Exit(Cancel As Integer) txtFName.BackColor = mlngBackColorOrigFName '退出文本框时,还原背景色 End Sub Private Sub txtLName_Enter() mlngBackColorOrigLName = txtLName.BackColor '当进入文本框,保存原始的背景色 txtLName.BackColor = mclngBackColor '将背景色设置成我们喜欢的颜色 End Sub Private Sub txtLName_Exit(Cancel As Integer) txtLName.BackColor = mlngBackColorOrigLName '退出文本框时,还原背景色 End Sub
将这段代码放到一个窗体模块中,添加 2 个文本框,命名为 txtFName 和 txtLName 。打开这个窗体,当光标进入到这 2 个文本框中时(OnEnter 事件发生),文本框的背景颜色变成了淡蓝色。当光标退出这 2 个文本框时 (OnExit 事件发生),文本框的背景颜色还原成原来的颜色。感觉很酷吧?但是来看看我们遇到了什么吧。我们需要在窗体顶部为每一个我们想使用该效果的控件定义一个变量,来保存旧的背景色。如果只有一两个控件需要使用该效果,那还算好。但是如果有 20 个或 40 个控件需要使用该效果,那该怎么办?更进一步来讲,我们不仅需要变量来存储这些东西,我们还需要为每一个控件设置 OnEnter 和 OnExit 这 2 个事件,乘以 20 或 40 个控件,那就是40 或 80 个事件代码,够痛苦吧?
幸运的是,我们可以创建类来为控件建模,比如一个文本框。我将选用这种简单的控件作为示例,以方便你理解它的工作原理,之后我会为其添加故障排查相关的代码。
以下是类 dclsCtlTextBox 中的代码。它代表着文本框的类,很简单也相当有用。(点击该连接:Access框架研究系列之4 控件类示例下载本章所有示例代码文件)
Option Compare Database Option Explicit '定义一个带有事件的文本框 Private WithEvents mtxt As TextBox '一个常量被定义为[Event Procedure] Private Const mcstrEventProcedure="[Event Procedure]" '漂亮的蓝色颜色代号,将会被设置成文本框的背景色 Private Cosnt mclngBackColor As Long=16777088 '保存文本框原来背景颜色的地方 Private mlngBackColorOrig As Long
注意到没有?我们有一个保存原背景色的变量;有一个常量用来保存我们选择的颜色,当文本框获得焦点之后,文本框的背景色会被设置成它;还有一个保存指向某个具体的文本框的指针的变量,而且被定义成能响应事件(Withevents)!这告诉程序这个类将会响应这个控件的事件。
'每个类的 Init 函数初始化这个类,传入指向某个具体控件的指针 Sub Init(ByRef ltxt as TextBox) '将传入的指针保存到类的私有变量中 set mtxt=ltxt '将控件的 OnEnter 属性设置为 [Event Procedure] mtxt.OnEnter = mcstrEventProcedure '为 OnExit 做相同的设置 mtxt.OnExit = mcstrEventProcedure End Sub
接下来,我们有一个 Init 子程序,传入一个指向某个具体文本框的指针,我们将这个指针保存在类的头部定义的私有变量中。同时我们也将这个变量的 OnEnter 和 OnExit 属性设置成字符串 [Event Procedure]。
解释:将窗体或者控件的任何一个事件的事件属性设置成字符串 “[Event Procedure]”,会导致该窗体或控件在发生该事件时,为这个事件做广播,通知所有指向该窗体或控件的 WithEvents 变量执行该事件代码。因为这个原因,在类的 Init() 方法中,我们总是会将我们想要处理的事件的事件属性设置成 [Event Procedure],这样,当对象发生这个事件时,类中的事件代码就能够被执行。
'每个类的 Term 方法清除所有指向类中的对象的指针 Sub Term() '将指向控件的指针设置成Nothing Set mtxt=Nothing End Sub '这里有文本框的 OnEnter 和 OnExit 事件的事件处理代码 Private Sub mtxt_Enter() '当文本框获得焦点时,将原来的背景色保存下来 mlngBackColorOrig = mtxt.BackColor '将文本框的背景颜色设置成我们预先定义的颜色 mtxt.BackColor = mclngBackColor End Sub Private Sub mtxt_Exit(Cancel As Integer) '当文本框失去焦点时,还原其背景颜色 mtxt.BackColor = mlngBackColorOrig End Sub
Term 方法用来释放或清除指向文本框控件的指针。最后文本框的OnEnter和OnExit事件的事件代码处理文本框的背景颜色变化和还原。
设计好了 dclsTextBox 类之后,我们就可以开始为每个我们想控制的文本框做类的初始化了。我将使用我的示例数据库中的代码来处理4个文本框。这些代码保存在窗体 frmPeople2中。(点击该连接:Access框架研究系列之4 控件类示例下载本章所有示例代码文件)
Option Compare Database Option Explicit Private fdclsCtlTextBoxFName As dclsCtlTextBox Private fdclsCtlTextBoxLName As dclsCtlTextBox Private fdclsCtlTextBoxWeight As dclsCtlTextBox Private fdclsCtlTextBoxHeight As dclsCtlTextBox
我们定义了类的 4 个变量,每个用一个不同的名字。
Private Sub Form_Open(Cancel As Integer) Set fdclsCtlTextBoxFName = New dclsCtlTextBox fdclsCtlTextBoxFName.Init txtFName Set fdclsCtlTextBoxLName = New dclsCtlTextBox fdclsCtlTextBoxLName.Init txtLName Set fdclsCtlTextBoxWeight = New dclsCtlTextBox fdclsCtlTextBoxWeight.Init txtWeight Set fdclsCtlTextBoxHeight = New dclsCtlTextBox fdclsCtlTextBoxHeight.Init txtHeight End Sub
窗体的 Open 事件中,为这些类变量做初始化。
Private Sub Form_Close() fdclsCtlTextBoxFName.Term Set fdclsCtlTextBoxFName = Nothing fdclsCtlTextBoxLName.Term Set fdclsCtlTextBoxLName = Nothing fdclsCtlTextBoxWeight.Term Set fdclsCtlTextBoxWeight = Nothing fdclsCtlTextBoxHeight.Term Set fdclsCtlTextBoxHeight = Nothing End Sub
窗体的Close 事件帮我们做清扫工作。
就是这样!注意到没有?在窗体中,你找不到任何文本框控件的事件处理程序!原因当然就在于文本框类 dclsCtlTextBox 可以响应这些事件,我们没必要在窗体中再去响应了。(译者注:当然你完全可以在窗体中为该事件写事件代码,事件发生时,dclsCtlTextBox 中的事件代码会首先获得执行,然后程序会去执行窗体中的事件代码,也就是说,控件或窗体的事件完全可以在多个地方都获得响应和执行。)
我听到你已经开始抱怨了:“确实很酷,但是做初始化和善后清除工作的代码还是有不少啊!”你说的没错,使用这些繁琐的代码只是方便你理解,一旦你理解类的使用方法,我可以开始介绍一些技巧,简化我们的代码,如 frmPeople3 所示。(点击该连接:Access框架研究系列之4 控件类示例下载本章所有示例代码文件)
Option Compare Database Option Explicit Private fdclsCtlTextBoxFName As dclsCtlTextBox Private fdclsCtlTextBoxLName As dclsCtlTextBox Private fdclsCtlTextBoxWeight As dclsCtlTextBox Private fdclsCtlTextBoxHeight As dclsCtlTextBox Private Sub Form_Open(Cancel As Integer) ClassFactory fdclsCtlTextBoxFName, txtFName ClassFactory fdclsCtlTextBoxLName, txtLName ClassFactory fdclsCtlTextBoxWeight, txtWeight ClassFactory fdclsCtlTextBoxHeight, txtHeight End Sub Private Sub Form_Close() ClsDestroy fdclsCtlTextBoxFName ClsDestroy fdclsCtlTextBoxLName ClsDestroy fdclsCtlTextBoxWeight ClsDestroy fdclsCtlTextBoxHeight End Sub Function ClassFactory(ByRef ldclsCtlTextBox As dclsCtlTextBox, ByRef ltxt As TextBox) Set ldclsCtlTextBox = New dclsCtlTextBox ldclsCtlTextBox.Init ltxt End Function Function ClsDestroy(ByRef ldclsCtlTextBox As dclsCtlTextBox) ldclsCtlTextBox.Term Set ldclsCtlTextBox = Nothing End Function
窗体 frmPeople3 中使用了类工厂(ClassFactory)函数和类清除(ClsDestroy)函数。
如果使用集合(Collection)去保存我们的控件类变量,我们就不再需要为每个控件都去定义一个类变量了,代码就更加的简洁了!如 frmPeople4 所示。(点击该连接:Access框架研究系列之4 控件类示例下载本章所有示例代码文件)
Option Compare Database Option Explicit Private colClasses As Collection Private Sub Form_Open(Cancel As Integer) Set colClasses = New Collection ClassFactory txtFName ClassFactory txtLName ClassFactory txtWeight ClassFactory txtHeight End Sub Private Sub Form_Close() ClsDestroy End Sub Function ClassFactory(ByRef ltxt As TextBox) Dim ldclsCtlTextBox As dclsCtlTextBox Set ldclsCtlTextBox = New dclsCtlTextBox ldclsCtlTextBox.Init ltxt colClasses.Add ldclsCtlTextBox, ltxt.Name End Function Function ClsDestroy() Dim obj As Object For Each obj In colClasses obj.Term Next obj Set colClasses = Nothing End Function
是不是更加的简洁了?我们可以创建一个窗体类来帮助我们做这些事情!!这正是后面章节要做的事情。
译注:如果说前3篇讲得都是很抽象概念的话,那么从本篇开始往后,你将会非常具体的了解 Access 开发框架的每一个细小的部分,从最基础的部分开始,到一个完整的框架构成。
(点击该连接:Access框架研究系列之4 控件类示例下载本章所有示例代码文件)
受教了,写的不错,为不会用类的开发人员指明了一条道路
感谢支持!
写得真好,谢谢你的分享
感谢支持,欢迎拍砖。